咔叽游戏

 找回密码
 立即注册

QQ登录

只需一步,快速开始

搜索
查看: 331|回复: 0

[DOS/BAT] 变量延迟详解 call setlocal

[复制链接]
  • TA的每日心情
    无聊
    2019-4-21 13:02
  • 签到天数: 3 天

    [LV.2]圆转纯熟

    发表于 2020-8-15 11:36:03 | 显示全部楼层 |阅读模式
    对于批处理新手而言,“变量延迟”这个概念很可能闻所未闻,但是,它却像一堵横亘在你前进道路上的无形高墙,你感受不到它的存在,但当你试图往前冲时,它会把你狠狠地弹回来,让你无法逾越、无功而返;而一旦找到了越过它的方法,你就会发现,在for的世界里,前面已经是一片坦途,而你对批处理的理解,又上升到了一个新的境界。
      例如,你编写了这样一个代码:

    @echo off
    set num=0&&echo %num%
    pause你的本意是想对变量num赋值之后,再把这个值显示出来,结果,显示出来的并不是0,而是显示:ECHO 处于关闭状态。
      之所以会出错,是因为“变量延迟”这个家伙在作怪。
      在讲解变量延迟之前,我们需要了解一下批处理的执行过程,它将有助于我们深入理解变量延迟。
      批处理的执行过程是怎样的呢?
      “自上而下,逐条执行”,我想,这个经典的说法大家都已经耳熟能详了,没事的时候倒着念,也还别有一番古韵呢^_^,但是,我想问大家的是,大家真的深刻地理解了这句话的含义了吗?
      “自上而下”,这一条和我们本节的讲解关系不大,暂时略过不说,后一条,“逐条执行”和变量延迟有着莫大的干系,它是我们本节要关注的重点。
      很多人往往认为一行代码就是一条语句,从而把“逐条执行”与“逐行执行”等同起来,这就大错特错了。
      莫非“逐条执行”里暗藏着玄机?
      正是如此。
      “逐条”并不等同于“逐行”。这个“条”,是“一条完整的语句”的意思,并不是指“一行代码”。在批处理中,是不是一条完整的语句,并不是以行来论的,而是要看它的作用范围。
      什么样的语句才算“一条完整的语句”呢?
      1、在复合语句中,整个复合语句是一条完整的语句,而无论这个复合语句占用了多少行的位置。常见的复合语句有:for语句、if……else语句、用连接符&、||和&&连接的语句,用管道符号|连接的语句,以及用括号括起来的、由多条语句组合而成的语句块;
      2、在非复合语句中,如果该语句占据了一行的位置,则该行代码为一条完整的语句。
      例如:

    @echo off
    set num=0
    for /f %%i in ('dir /a-d /b *.exe') do (
    set /a num+=1
    echo num 当前的值是 %num%
    )
    echo 当前目录下共有 %num% 个exe文件
    dir /a-d /b *.txt|findstr "test">nul&&(
    echo 存在含有 test 字符串的文本本件
    )||echo 不存在含有 test 字符串的文本文件
    if exist test.ini (
    echo 存在 test.ini 文件
    ) else echo 不存在 test.ini 文件
    pause上面的代码共有14行,但是只有完整的语句只有7条,它们分别是:
      第1条:第1行的echo语句;
      第2条:第2行的set语句;
      第3条:第3、4、5、6行上的for复合语句;
      第4条:第7行的echo语句;
      第5条:第8、9、10行上用&&和||连接的复合语句;
      第6条:第11、12、13行上的if……else复合语句;
      第7条:第14行上的pause语句。
      在这里,我之所以要花这么长的篇幅来说明一行代码并不见得就是一条语句,是因为批处理的执行特点是“逐条”执行而不是“逐行”执行,澄清了这个误解,将会更加理解批处理的预处理机制。
      在代码“逐条”执行的过程中,cmd.exe这个批处理解释器会对每条语句做一些预处理工作,这就是批处理中大名鼎鼎的“预处理机制”。
      预处理的大致情形是这样的:首先,把一条完整的语句读入内存中(不管这条语句有多少行,它们都会被一起读入),然后,识别出哪些部分是命令关键字,哪些是开关、哪些是参数,哪些是变量引用……如果代码语法有误,则给出错误提示或退出批处理环境;如果顺利通过,接下来,就把该条语句中所有被引用的变量及变量两边的百分号对,用这条语句被读入内存之就已经赋予该变量的具体值来替换……当所有的预处理工作完成之后,批处理才会执行每条完整语句内部每个命令的原有功能。也就是说,如果命令语句中含有变量引用(变量及紧邻它左右的百分号对),并且某个变量的值在命令的执行过程中被改变了,即使该条语句内部的其他地方也用到了这个变量,也不会用最新的值去替换它们,因为某条语句在被预处理的时候,所有的变量引用都已经被替换成字符串常量了,变量值在复合语句内部被改变,不会影响到语句内部的其他任何地方。
      顺便说一下,运行代码[code20]之后,将在屏幕上显示当前目录下有多少个exe文件,是否存在含有 test 字符串的文本文件,以及是否存在 test.ini 这个文件等信息。让很多人百思不得其解的是:如果当前目录下存在exe文件,那么,有多少个exe文件,屏幕上就会提示多少次 "num 当前的值是 0" ,而不是显示1到N(N是exe文件的个数)。
      结合上面两个例子,我们再来分析一下,为什么这两段代码的执行结果和我们的期望有一些差距。
      在[code19]中,set num=0&&echo %num%是一条复合语句,它的含义是:把0赋予变量num,成功后,显示变量num的值。
      虽然是在变量num被赋值成功后才显示变量num的值,但是,因为这是一条复合语句,在预处理的时候,&&后的%num%只能被set语句之前的语句赋予变量num的具体值来替换,而不能被复合语句内部、&&之前的set语句对num所赋予的值来替换,可见,此num非彼num。可是,在这条复合语句之前,我们并没有对变量num赋值,所以,&&之后的%num%是空值,相当于在&&之后只执行了 echo 这一命令,所以,会显示 echo 命令的当前状态,而不是显示变量num的值(虽然该变量的值被set语句改变了)。
      在[code20]中,for语句的含义是:列举当前目录下的exe文件,每发现一个exe文件,变量num的值就累加1,并显示变量num的值。
      看了对[code19]的分析之后,再来分析[code20]就不再那么困难了:第3、4、5行上的代码共同构成了一条完整的for语句,而语句"echo num 当前的值是 %num%"与"set /a num+=1"同处复合语句for的内部,那么,第4行上set改变了num的值之后,并不能对第5行上的变量num有任何影响,因为在预处理阶段,第5行上的变量引用%num%已经被在for之前就赋予变量num的具体值替换掉了,它被替换成了0(是被第2行上的set语句赋予的)。
      如果想让代码[code19]的执行结果中显示&&之前赋予num的值,让代码[code20]在列举exe文件的时候,从1到N地显示exe文件的数量,那又该怎么办呢?
    对代码[code19],可以把用&&连接复合语句拆分为两条单独的语句,写成:
    @echo off
    set num=0
    echo %num%
    pause  
    但是,这不是我们这次想要的结果。
      对这两段代码都适用的办法是:使用变量延迟扩展语句,让变量的扩展行为延迟一下,从而获取我们想要的值。
      在这里,我们先来充下电,看看“变量扩展”有是怎么一回事。
      用CN-DOS里批处理达人willsort的原话,那就是:“在许多可见的官方文档中,均将使用一对百分号闭合环境变量以完成对其值的替换行为称之为“扩展(expansion)”,这其实是一个第一方的概念,是从命令解释器的角度进行称谓的,而从我们使用者的角度来看,则可以将它看作是引用(Reference)、调用(Call)或者获取(Get)。”(见:什么情况下该使用变量延迟?http://www.cn-dos.net/forum/viewthread.php?tid=20733)说得直白一点,所谓的“变量扩展”,实际上就是很简单的这么一件事情:用具体的值去替换被引用的变量及紧贴在它左右的那对百分号。
      既然只要延迟变量的扩展行为,就可以获得我们想要的结果,那么,具体的做法又是怎样的呢?
      一般说来,延迟变量的扩展行为,可以有如下选择:
      1、在适当位置使用 setlocal enabledelayedexpansion 语句;
      2、在适当的位置使用 call 语句。
    使用 setlocal enabledelayedexpansion 语句,那么,[code19]和[code20]可以分别修改为:

    @echo off
    setlocal enabledelayedexpansion
    set num=0&&echo !num!
    pause复制内容到剪贴板 代码:@echo off
    set num=0
    setlocal enabledelayedexpansion
    for /f %%i in ('dir /a-d /b *.exe') do (
    set /a num+=1
    echo num 当前的值是 !num!
    )
    echo 当前目录下共有 %num% 个exe文件
    dir /a-d /b *.txt|findstr "test">nul&&(
    echo 存在含有 test 字符串的文本本件
    )||echo 不存在含有 test 字符串的文本文件
    if exist test.ini (
    echo 存在 test.ini 文件
    ) else echo 不存在 test.ini 文件
    pause  使用第call语句,那么,[code19]和[code20]可以分别修改为: 复制内容到剪贴板 代码:
    @echo off
    set num=0&&call echo %%num%%
    pause
    代码:

    @echo off
    set num=0
    for /f %%i in ('dir /a-d /b *.exe') do (
    set /a num+=1
    call echo num 当前的值是 %%num%%
    )
    echo 当前目录下共有 %num% 个exe文件
    dir /a-d /b *.txt|findstr "test">nul&&(
    echo 存在含有 test 字符串的文本本件
    )||echo 不存在含有 test 字符串的文本文件
    if exist test.ini (
    echo 存在 test.ini 文件
    ) else 不存在 test.ini 文件
    pause由此可见,如果使用 setlocal enabledelayedexpansion 语句来延迟变量,就要把原本使用百分号对闭合的变量引用改为使用感叹号对来闭合;如果使用call语句,就要在原来命令的前部加上 call 命令,并把变量引用的单层百分号对改为双层。 其中,因为call语句使用的是双层百分号对,容易使人犯迷糊,所以用得较少,常用的是使用 setlocal enabledelayedexpansion 语句(set是设置的意思,local是本地的意思,enable是能够的意思,delayed是延迟的意思,expansion是扩展的意思,合起来,就是:让变量成为局部变量,并延迟它的扩展行为)。
      通过上面的分析,我们可以知道:
      1、为什么要使用变量延迟?因为要让复合语句内部的变量实时感知到变量值的变化。
      2、在哪些场合需要使用变量延迟语句?在复合语句内部,如果某个变量的值发生了改变,并且改变后的值需要在复合语句内部的其他地方被用到,那么,就需要使用变量延迟语句。而复合语句有:for语句、if……else语句、用连接符&、||和&&连接的语句、用管道符号|连接的语句,以及用括号括起来的、由多条语句组合而成的语句块。最常见的场合,则是for语句和if……else语句。
      3、怎样使用变量延迟?
      方法有两种:
      ① 使用 setlocal enabledelayedexpansion 语句:在获取变化的变量值语句之前使用setlocal enabledelayedexpansion,并把原本使用百分号对闭合的变量引用改为使用感叹号对来闭合;
      ② 使用 call 语句:在原来命令的前部加上 call 命令,并把变量引用的单层百分号对改为双层。
      “变量延迟”是批处理中一个十分重要的机制,它因预处理机制而生,用于复合语句,特别是大量使用于强大的for语句中。只有熟练地使用这一机制,才能在for的世界中如鱼得水,让自己的批处理水平更上一层楼。很多时候,对for的处理机制,我们一直是雾里看花,即使偶有所得,也只是只可意会难以言传。希望大家反复揣摩,多加练习,很多细节上的经验,是只有通过大量的摸索才能得到的。Good Luck!
    变量延迟(setlocal)之浅见

    变量延迟,浅见认为就是变量预处理,在事先声明变量,告诉cmd环境哪个先哪个后。默认情况下是停用,可以用两种方法启用/停用:
    一、cmd /v:on 和cmd /v:off ,范围在cmd这个环境直至exit 出现退出cmd
    二、setlocal enabledelayedexpansion和setlocal disabledelayedexpansion范围在批处理文件范围内,直至endlocal出现中止.
    先看看官方帮助set /?后以几个批处理代码注释解释。
    考虑到读取一行文本时所遇到的目前扩充的限制时,延迟环境变量扩充是很有用的,而不是执行的时候。以下例子说明直接变量扩充的问题:
        set VAR=before
        if "%VAR%" == "before" (
            set VAR=after
            if "%VAR%" == "after" @echo If you see this, it worked
        )
    不会显示消息,因为在读到第一个 IF 语句时,BOTH IF 语句中的 %VAR% 会被代替;原因是: 它包含 IF 的文体,IF 是一个复合语句。所以,复合语句中的 IF 实际上是在比较 "before" 和"after",这两者永远不会相等。同样,以下这个例子也不会达到预期效果:
        set LIST=
        for %i in (*) do set LIST=%LIST% %i
        echo %LIST%
    原因是,它不会在目前的目录中建立一个文件列表,而只是将LIST 变量设成找到的最后一个文件。这也是因为 %LIST% 在FOR 语句被读取时,只被扩充了一次;而且,那时的 LIST 变量是空的。因此,我们真正执行的 FOR 循环是:
        for %i in (*) do set LIST= %i
    这个循环继续将 LIST 设成找到的最后一个文件。延迟环境变量扩充允许您使用一个不同的字符(惊叹号)在执行时间扩充环境变量。如果延迟的变量扩充被启用,可以将上面例子写成以下所示,以达到预期效果:
        set VAR=before
        if "%VAR%" == "before" (
            set VAR=after
            if "!VAR!" == "after" @echo If you see this, it worked
        )
        set LIST=
        for %i in (*) do set LIST=!LIST! %i
        echo %LIST%
    如果命令扩展名被启用,有几个动态环境变量可以被扩展,但不会出现在 SET 显示的变量列表中。每次变量数值被扩展时,这些变量数值都会被动态计算。如果用户用这些名称中任何一个定义变量,那个定义会替代下面描述的动态定义:
    %CD% - 扩展到当前目录字符串。
    %DATE% - 用跟 DATE 命令同样的格式扩展到当前日期。
    %TIME% - 用跟 TIME 命令同样的格式扩展到当前时间。
    %RANDOM% - 扩展到 0 和 32767 之间的任意十进制数字。
    %ERRORLEVEL% - 扩展到当前 ERRORLEVEL 数值。
    %CMDEXTVERSION% - 扩展到当前命令处理器扩展名版本号。
    %CMDCMDLINE% - 扩展到调用命令处理器的原始命令行。
    开始批处理文件中环境改动的本地化操作。在执行 SETLOCAL 之后所做的环境改动只限于批处理文件。要还原原先的设置,必须执行 ENDLOCAL。达到批处理文件结尾时,对于该批处理文件的每个尚未执行的 SETLOCAL 命令,都会有一个隐含的 ENDLOCAL 被执行。
    SETLOCAL
    如果命令扩展名被启用,SETLOCAL 会如下改变:
    SETLOCAL 批命令现在可以接受可选参数:
    ENABLEEXTENSIONS / DISABLEEXTENSIONS
    启动或停用命令处理器扩展名。详细信息,请参阅 CMD /?。
    ENABLEDELAYEDEXPANSION / DISABLEDELAYEDEXPANSION
    启动或停用延缓环境变量扩展名。详细信息,请
    参阅 SET /? 。
    无论在 SETLOCAL 命令之前它们的设置是什么,这些修改会一直保留到匹配的 ENDLOCAL 命令。如果有一个参数,SETLOCAL 命令将设置 ERRORLEVEL 的值。如果有两个有效参数中的一个,该值则为零。用下列技巧,您可以在批脚本中使用这个来决定扩展名是否可用:
    VERIFY OTHER 2>nul
    SETLOCAL ENABLEEXTENSIONS
    IF ERRORLEVEL 1 echo Unable to enable extensions
    这个方法之所以有效,是因为在 CMD.EXE 的旧版本上,SETLOCAL不设置 ERRORLEVEL 值。具有不正确参数的 VERIFY 命令将ERRORLEVEL 值初始化成非零值。
    官方解释有些让人犯迷糊,以下几个代码注释部分来解释变量延迟,纰漏之处,请高手斧正.

    @echo off&setlocal enabledelayedexpansion
    ::第一方演示变量延迟,当输出if you ..延迟启动
    ::var重复赋值,第一个%var%取的是before
    ::第二个!var!取的是after,若不开启延迟变量
    ::不显示因!VAR!取的是before
    set VAR=before
    if "%VAR%" == "before" (
    set VAR=after
    if "!VAR!" == "after" @echo If you see this, it worked
    )
    pause>nul
    @echo off&setlocal enabledelayedexpansion
    :: 演示变量延迟,用setlocal disabledelayedexpansion
    :: 和setlocal enabledelayedexpansion 相互切换
    :: echo %var% 取set var=fds 的值,而echo !var!
    :: 取for复合语句中set var=%%i的值;%var%的值与变量延迟
    :: setlocal开关无关,但!var!的值与之相关。当变量延迟
    :: 处于开状态则取%%i的赋值,反之则取!var!本身.
    set var=fds
    for /l %%i in (1,1,6) do (
    set var=%%i
    echo %var%
    echo !var!
    )
    pause>nul&exit
    @echo off&setlocal enabledelayedexpansion
    ::变量里套变量延迟演示
    set a=40000
    set b=df
    set a%b%=70000
    set c=!a%b%!
    echo %c%
    pause>nul
    @echo off&setlocal enabledelayedexpansion
    ::显示2个随机数并截取各数字求和
    mode con:cols=40 lines=20 1>nul
    color a1
    set %random%=%random%
    for /f "delims=" %%i in ('set') do set num=%%i&call echo %%num%%&goto be
    :be
    for /f "tokens=1,2 delims==" %%j in ("%num%") do (
    set/a a=%%j
    set/a b=%%k
    )
    for /f %%l in ("%a%%b%") do (
    set/a a=%%l
    set/a b=%%l
    set/a a0=%a:~0,1%
    set/a a1=%a:~1,1% 2>nul&set/a a1+=!a0!
    set/a a2=%a:~2,1% 2>nul&set/a a2+=!a1!
    set/a a3=%a:~3,1% 2>nul&set/a a3+=!a2!
    set/a a4=%a:~4,1% 2>nul&set/a a4+=!a3!
    set/a b0=%b:~0,1%
    set/a b1=%b:~1,1% 2>nul&set/a b1+=!b0!
    set/a b2=%b:~2,1% 2>nul&set/a b2+=!b1!
    set/a b3=%b:~3,1% 2>nul&set/a b3+=!b2!
    set/a b4=%b:~4,1% 2>nul&set/a b4+=!b3!
    )
    set/a b4+=%a4%
    echo 和为:%b4%
    pause>nul以下内容为mq0036个人补充:
    先来看个变量延迟的例子:

    @echo off

    setlocal
    set aa=aaa:bbb
    call :ck %aa%
    echo return=%str%
    call :ddd
    goto :eof

    :ck
    setlocal EnableDelayedExpansion
    if "a"=="a" (set str2=ErrorOperation) else (
    echo else
    for /f "tokens=1,* delims=:" %%m in ("%~1") do (
    set str1=%%~m
    if /I "!str1!"=="aaa" set str2=%%~n
    )
    )
    endlocal & set str=%str2%
    goto :eof

    :ddd
    echo %zzz%
    set zzz=old
    goto :eof
    相信各位对上面的程序都能看懂,不过我这里还要写点废话解释解释,高手请跳过。
    1.使用setlocal设置变量为局部变量,结束标志是endlocal,如果不是有endlocal则作用范围表示到当前文件结束.
    2.变量延迟使用setlocal EnableDelayedExpansion和setlocal DisableDelayedExpansion,如果不使用setlocal DisableDelayedExpansion则作用范围表示到当前文件结束.
          说明:DisableDelayedExpansion只是关闭变量延迟,也就是在这个语句后面的无法使用变量延迟的功能(后面还有讲解)
    3.if语句后如果要执行多条语句需要把多条语句使用括号括起来,当使用else时,即使if后只有单条语句,也要括起来。
    BAT语法认为括号中的语句就是一条语句。
    程序说明:
    说变量延迟就要说到局部变量,如果他们嵌套使用,各个变量的取值会怎么样?
    第三行,设置局部变量
    :ck子程序的功能,是利用延迟把aa变量中根据冒号(:)分割提取字符串,并且带回分割后的字符串
    :ddd子程序则是为了验证程序前面的setlocal的嵌套的作用域
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。
    验证一:
    把第三行的setlocal去掉,然后多次运行程序,可以看出第一次执行时,echo %zzz%输出的是ECHO is off.后面再次执行的都输出了old字符串。
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,输入程序文件名运行
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。

    验证二:
    使用endlocal & set str=%str2%是为了把局部变量返回主调函数中
    多次调用执行该文件,变量echo %zzz%中的值都是空
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。

    验证三:
    在BAT文件中的一部分是局部变量,一部分是全局变量。修改程序代码如下:
    setlocal
    echo %aa%
    set aa=aaa:bbb
    ::endlocal
    call :ddd
    endlocal
    goto :eof
    :ddd
    echo %zzz%
    set zzz=old
    goto :eof
    通过改变endlocal的位置可以看到,在调用语句的后面,但在子程序的前面使用,则会起到局部变量的效果,当放到调用语句的前面则是全局变量的效果。这里测试的是在主程序中调用setlocal的功能,所以endlocal也必须在主程序中使用。
    而且setlocal跟子程序有关,如果在子程序中使用setlocal,则在该子程序结束前的endlocal有效,如果不写endlocal则默认作用域到子程序结束,也就是在子程序中使用setlocal则作用域不会超出子程序。看下面的示例:
    @echo off
    echo %aa%
    set aa=aaa:bbb
    call :bbb
    call :ddd
    goto :eof
    :bbb
    setlocal
    echo %zzz%
    set zzz=old
    ::endlocal
    echo %xxx%
    set xxx=xxx
    goto :eof
    :ddd
    echo %y%
    set y=yyyy
    运行以上程序,把:bbb子程序中的endlocal启用和禁用,可以查看变量%zzz%和%xxx%的值,
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。

    验证四:
    把if "a"=="a" (set str2=ErrorOperation)...... 这个语句中的括号拿掉,不管条件是否成立,"a"=="a"或"a"=="b",则都会执行else里的语句
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。

    验证五:
    延迟的启用与禁用,修改ck子程序,如下:
    :ck
    setlocal EnableDelayedExpansion
    if "a"=="b" (set str2=ErrorOperation)  else (
    echo else
    for /f "tokens=1,* delims=:" %%m in ("%~1") do (
    set str1=%%~m
    if /I "!str1!"=="aaa" set str2=%%~n
    )
    )
    ::setlocal DisableDelayedExpansion
    for /l %%i in (1,1,3) do (set num=%%i
    echo !num!)
    setlocal DisableDelayedExpansion
    goto :eof
    把setlocal DisableDelayedExpansion放到for语句之前和之后的区别,你自己可以测试看看效果,从这里个程序可以看到启用和禁用的区别。
    程序运行方式:把程序保存为bat文件,运行cmd并切换到程序所在目录,运行程序,如果修改了程序则关闭当前cmd窗口重新打开cmd。
    以上就是变量延迟详解 call setlocal的详细内容,更多关于call setlocal的资料请关注咔叽论坛其它相关文章!

    原文地址:https://www.jb51.net/article/193245.htm

    QQ|免责声明|小黑屋|手机版|Archiver|咔叽游戏

    GMT+8, 2024-3-29 03:36

    Powered by Discuz! X3.4

    © 2001-2023 Discuz! Team.

    快速回复 返回顶部 返回列表